治疗宠物宏(魔兽世界血精灵牧师{治疗}的基本宏有些什么呢)

1.有宠物时xx，没有时xx

#showtooltip

/cast [pet,@pet,nodead]防恐惧结界;暗影恶魔

/petattack

/cast 遁影 ←宝宝那个技能。。。

解释：没有宝宝的话就是招宝宝，有宝宝后是给他上CS。无脑按的话是遁影和攻击你的目标。

我觉得这个蛮好用的，比如打战士 直接沉默了按2下宏就能保证宝宝的完整输出了。竞技场里也可以避免宝宝乱跑乱打人

2.对指定名字的人施放xx

#showtooltip

/cast [@pname]驱散魔法

解释：pname换成队友名字，最简单的宏 也最实用

3.防止多次点击取消形态/范围选框

#showtooltip

/cast !群体驱散

解释：多次按键驱散的框框不会消失

4.目标的目标是队友时对目标的目标xx

#showtooltip

/cast [help][@targettarget,help,nodead][]虔信之跃

解释：目标如果是友方，拽他；目标的目标如果是友方 拽目标的目标。

我觉得竞技场里辅助性的技能还是尽量借助宏比较好，频繁切目标的话很耽误事=w=，同理可以吧这个宏换成盾 驱散什么的，看个人喜好拉。

5.取消buff

#showtooltip

/cancelaura 影散

/cast 心灵尖啸

解释：这是我个人喜欢用的宏，有时候变球后，对方在读重要的技能或者别的什么的反正你想要取消掉球，按一下就好了，PS：在变球时只按1下就可以取消球，按2下才会放恐惧。

6.优先敌对焦点施放xx

#showtooltip

/cast [@focus,harm,nodead][]沉默

解释：有敌对未亡的焦点目标就沉默焦点，否则就是个普通沉默。

7.优先敌对目标→敌对焦点→普通的灭

#showtooltip

/cast [harm,nodead][@focus,harm,nodead][]暗言术：死

解释：目标是敌人的话就灭他，其他情况灭焦点，再其他情况……(还有啥情况)就是个普通的灭。

8.按顺序释放(2种甲切换)

#showtooltip

/castsequence 心灵之火,专注意志

解释：2种甲切换。

9.左键xx 右键xx

#showtooltip

/cast [button:1]真言术：韧;[button:2]防护暗影

解释：左键加耐力，右键加暗抗。能省一个是一个。。。

10.简易坐骑宏(真的很简易……

#showtooltip

/cast [flyable]灰机;大炮

解释：前面是飞行后面是陆地 - -

11.判断形态的(是否在潜行、暗影形态、变形状态下)

#showtooltip

/cast [form]渐隐术;快速治疗

解释：暗影状态下用渐隐，非暗影状态下用快速治疗(只是举个例子。

12.最后 万用灭宏=_,=

#showtooltip

/stopcasting

/cast [@mouseover,exists,harm][harm,nodead][@focus,harm,nodead][@targettarget,harm,nodead][]暗言术：灭

解释：优先级分别是：鼠标指向的敌人 → 敌对目标 → 敌对焦点目标 → 敌对的“目标的目标” → 其他情况 还有啥！

b.暗影魔宏:

----当目标友好,目标的目标敌对的时候.攻击目标的目标

----当目标敌对.攻击目标.如果以上都不满足,,不施放

----施放暗影魔后,宠物主动攻击

----施放宠物技能,暗影爬行<-----暗影魔的伤害也是不低的.希望暗影爬行这个技能大家米忽略

#showtooltip 暗影恶魔

/cast [nopet,harm][nopet,target=targettarget,harm] 暗影恶魔

/petattack [harm][target=targettarget,harm]

/petaggressive

/cast [harm][target=targettarget,harm] 暗影爬行

----/petaggressive 使得暗影魔变成主动攻击,若担心ADD,则改成/petdefensive保护状态

f.治疗石宏:

----术士的糖都是良莠不齐的....好多都缩水

----不管治疗石能加多少血,都叫极效治疗石,,所以用这个宏只要包里有糖就能看到了.

#showtooltip

/use 极效治疗石

j救命宏:

----穿着布衣的牧师,非常非常脆弱

----用完能用的技能后做个表情,大家就知道你有危险了,,会看下你是否需要帮助

#showtooltip 绝望祷言

/stopcasting

/use 13

/cast 绝望祷言

/use 极效治疗石

/e Godess light my path_

--*/use 13 使用装备栏上第13个空格的饰品,就是上边那个饰品.避免出现未装备的错误*

该语句只在对应位置为战斗大师时使用.其他时候可以删除.

4.2 延时语句

/in

这个命令很有趣。它是基于第一行开始执行的时间向后数秒并继续执行后面的语句。比如：

/e 摸了摸%t温暖的皮毛

/in 2 /e 揪了揪%t毛茸茸的尾巴

/in 4 /e 又揪了揪%t毛茸茸的尾巴

/in 6 /e 发现%t的尾巴起毛了

这个宏你可以找个小D当目标去测试一下

4.3 脚本

通过脚本来实现施放技能后的喊话可以有效解决 /in 或施法失败导致的刷屏.

但脚本字符占用很多,所以能够容纳的喊话内容有限.

/脚本 F=F or CreateFrame("frame")F:RegisterEvent("UNIT_SPELLCAST_SUCCEEDED")F:SetScript("OnEvent",function()if arg1=="player"and arg2=="A1"then SendChatMessage("A2","A3")F:SetScript("OnEvent",nil)end;end)

/施放 [exists]A1

A1:是你要施放的技能名称.

A2:是你要说的话,不要太长.

A3:是你要说话的频道.

表情:emote

公会:guild

小队:party

团队:raid

喊:yell

说:say

这个是以反恐结界为例子:

/stopmacro [harm]

/脚本 F=F or CreateFrame("frame")F:RegisterEvent("UNIT_SPELLCAST_SUCCEEDED")F:SetScript("OnEvent",function()if arg1=="player"and arg2=="防护恐惧结界"then SendChatMessage("已经对%T施放了[防护恐惧结界]","raid")F:SetScript("OnEvent",nil)end;end)

/施放 防护恐惧结界

下面这个是另外一种写法的脚本:

优点：技能冷却完毕时，施放技能喊话，否则通报剩余CD时间,有效喊话容量较大

缺点：昏迷等特殊情况，即使技能冷却完毕，依旧无法释放技能，于是按宏导致刷屏

#showtooltip 守护之魂

/stopcasting

/stopmacro [noexists]

/stopmacro [harm]

/脚本 local s,d,_,t=GetSpellCooldown("守护之魂")t=s==0 and"吟唱：以泰瑞尔之圣名，愿大天使的眷顾与 %t 同在..."or"的大天使守护还有"..ceil(s+d-GetTime()).."秒冷却"SendChatMessage(t,"EMOTE")

/cast 守护之魂

希望能对你有所帮助